KButton1

ボタンライブラリ

簡単にGUI部品を表示することができるようになります。

構文

KBSetup kbSetup = new KBSetup(papplet);
KButton button = new KButton(object, callFunction, x, y, width, height, radius);

• papplet : global(setup関数がある空間)のthis
• object : ボタンを使用する部分のthis(Object)
• callFunction : ボタンが押された際に呼ばれる関数名
• x : ボタンの左上のx座標
• y : ボタンの左上のy座標
• width : 横幅
• height : 縦幅
• radius : ボタンの角丸具合

メソッド

• 座標の設定
  Set button.set.position(x, y)
  ボタンの左上の角の座標を設定します。
  
• 大きさの設定
  Set button.set.size(width, height, radius)
  ボタンの縦幅、横幅、丸み具合を設定します。
  
• 背景画像の設定
  Set button.set.bgImage(image)
  ボタンの背景を単色から画像に変更します。
  image: PImage
• ボタンの色設定
  Set button.set.buttonColor(rectColor, rectEdgeColor)
  ボタンの背景色、輪郭線の色を設定します。
  rectColor: color
  rectEdgeColor: color
  
• ボタンのホバー時色設定
  Set button.set.buttonHoverColor(rectHoverColor)
  ボタンのカーソルホバー時の背景色を設定します。
  rectHoverColor: color
  
• ボタンの文字の設定
  Set button.set.label(text, labelSize)
  Set button.set.label(text, labelSize, font) ※overload
  ボタンに表示されるテキストを設定します。 text: String
  labelSize: float
  font: PFont
  
• ボタンの文字位置設定
  Set button.set.align(horizontal, vertical)
  ボタンに表示されるテキストの位置を設定します。
  
  • horizontal: int
    • LEFT
    • CENTER
    • RIGHT
  • vertical: int
    • TOP
    • CENTER
    • BOTTOM
• ボタンの文字色設定
  Set button.set.labelColor(textColor)
  ボタンに表示されるテキストの色を設定します。
  textColor: color
  
• ボタンの文字色設定
  Set button.set.labelFont(font)
  ボタンに表示されるテキストのフォントを設定します。
  font: PFont
  

サンプルコード

// kbSetup という変数名でなければならない
KBSetup kbSetup;
KButton buttonUp;
KButton buttonDown;
int counter = 0;

void setup() {
    size(500, 500);
    // mainのthis(papplet)を渡す、必ずsetup関数内で最初に記述
    kbSetup = new KBSetup(this);
    buttonUp = new KButton(this, "countUp", (width-150)/2 - 50, (height-60)/2 + 50, 100, 60, 0);
    buttonUp.set.buttonColor(color(110), color(50))
        .buttonHoverColor(color(170))
        .label("up", 15)
        .align(CENTER, CENTER)
        .labelColor(color(230, 230, 255));
    buttonDown = new KButton(this, "countDown", (width-150)/2 + 100 , (height-60)/2 + 50, 100, 60, 0);
    buttonDown.set.buttonColor(color(110), color(50))
        .buttonHoverColor(color(170))
        .label("down", 15)
        .align(CENTER, CENTER)
        .labelColor(color(230, 230, 255));
}

void draw() {
    background(255);
    fill(0);
    textAlign(CENTER, CENTER);
    textSize(30);
    text("counter: "+counter, width/2.0, height/2.0 - 50);
}

/*ボタン生成時に第2引数で設定した関数名*/
void countUp() {
    counter++;
    println("count up click", counter);
}

/*ボタン生成時に第2引数で設定した関数名*/
void countDown() {
    counter--;
    println("count down click", counter);
}